{ pkgs, lib, config, modulesPath, ... }:
let
  name = config.networking.hostName;
  nixosLibPath = (modulesPath + "/../lib");
  moduleList = import (modulesPath + "/module-list.nix");

  optionalPath = p: lib.optional (builtins.pathExists p) p;
in
assert builtins.pathExists nixosLibPath;
builtins.seq lib
builtins.seq modulesPath
builtins.seq moduleList
{
  imports = moduleList ++ [
    (modulesPath + "/testing/test-instrumentation.nix")
  ] ++ lib.concatLists [
    (optionalPath ./hardware-configuration.nix)
    (optionalPath ./dynamicism)
    (optionalPath ../../modules/dynamicism)
  ];

  system.switch.enable = true;
  documentation.enable = false;

  networking.hostName = "machine";

  boot.loader.grub = {
    enable = true;
    device = "/dev/vda";
    forceInstall = true;
  };

  nix = {
    package = pkgs.lixPackageSets.latest.lix;
    nixPath = [ "nixpkgs=${pkgs.path}" ];

    settings = {
      experimental-features = [ "nix-command" "pipe-operator" ];
      substituters = lib.mkForce [ ];
      hashed-mirrors = null;
      connect-timeout = 1;
    };
  };

  services.gotosocial = {
    enable = true;
    setupPostgresqlDB = true;
    settings = {
      application-name = "gotosocial-for-${name}";
      host = "${name}.local";
    };
  };

  dynamicism.for.gotosocial.enable = true;

  environment.pathsToLink = [ "/share" ];
  environment.variables = {
    "NIXOS_CONFIG" = "/etc/nixos/configuration.nix";
  };

  environment.shellAliases = {
    ls = "eza --long --header --group --group-directories-first --classify --binary";
  };
  environment.systemPackages = with pkgs; [
    eza
    fd
    ripgrep
  ];
}