{
  description = "MCP server for the Jortt accounting & invoicing API";

  inputs.nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";

  outputs = { self, nixpkgs }:
    let
      systems = [ "x86_64-linux" "aarch64-linux" "x86_64-darwin" "aarch64-darwin" ];
      forAllSystems = f: nixpkgs.lib.genAttrs systems (system: f nixpkgs.legacyPackages.${system});
      mkPackage = pkgs: pkgs.callPackage ./nix/package.nix { };
    in
    {
      packages = forAllSystems (pkgs: rec {
        jortt-mcp = mkPackage pkgs;
        default = jortt-mcp;
      });

      overlays.default = final: prev: {
        jortt-mcp = mkPackage final;
      };

      nixosModules.jortt-mcp = { pkgs, lib, ... }: {
        imports = [ ./nix/module.nix ];
        services.jortt-mcp.package =
          lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.jortt-mcp;
      };
      nixosModules.default = self.nixosModules.jortt-mcp;

      devShells = forAllSystems (pkgs: {
        default = pkgs.mkShell {
          packages = [ pkgs.nodejs_22 pkgs.typescript ];
        };
      });
    };
}